Ass1s

Привет, как в запросе можно получить курсы валют на каждую дату документа? Т.е. не курсы валют за период, а только на те даты документов, которые попадают в период выборки...Спасибо!

Привет! Получить курсы валют на дату документа (на разные даты) в одном запросе не сложно, но не каждый с этим справится. Тут надо проявить немного логики . Лови рабочий пример:

ВЫБРАТЬ
_ДемоСчетНаОплатуПокупателю.Ссылка КАК Ссылка,
_ДемоСчетНаОплатуПокупателю.Дата КАК Дата,
_ДемоСчетНаОплатуПокупателю.ВалютаДокумента КАК ВалютаДокумента,
_ДемоСчетНаОплатуПокупателю.СуммаОплаты КАК СуммаОплаты
ПОМЕСТИТЬ врДокументы
ИЗ
Документ._ДемоСчетНаОплатуПокупателю КАК _ДемоСчетНаОплатуПокупателю
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗЛИЧНЫЕ
врДокументы.Дата КАК Дата,
врДокументы.ВалютаДокумента КАК ВалютаДокумента
ПОМЕСТИТЬ врДатыВалюты
ИЗ
врДокументы КАК врДокументы
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
врДатыВалюты.Дата КАК Дата,
врДатыВалюты.ВалютаДокумента КАК ВалютаДокумента,
МАКСИМУМ(КурсыВалют.Период) КАК Период
ПОМЕСТИТЬ врДатаКурса
ИЗ
врДатыВалюты КАК врДатыВалюты
ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК КурсыВалют
ПО врДатыВалюты.ВалютаДокумента = КурсыВалют.Валюта
И врДатыВалюты.Дата >= КурсыВалют.Период

СГРУППИРОВАТЬ ПО
врДатыВалюты.Дата,
врДатыВалюты.ВалютаДокумента
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
врДатаКурса.Дата КАК Дата,
врДатаКурса.ВалютаДокумента КАК ВалютаДокумента,
врДатаКурса.Период КАК Период,
ЕСТЬNULL(КурсыВалют.Курс, 1) КАК Курс,
ЕСТЬNULL(КурсыВалют.Кратность, 1) КАК Кратность
ПОМЕСТИТЬ врКурсыВалютаНаДатыДокументов
ИЗ
врДатаКурса КАК врДатаКурса
ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.КурсыВалют КАК КурсыВалют
ПО врДатаКурса.Период = КурсыВалют.Период
И врДатаКурса.ВалютаДокумента = КурсыВалют.Валюта
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
врДокументы.Ссылка КАК Ссылка,
врДокументы.Дата КАК Дата,
врДокументы.ВалютаДокумента КАК ВалютаДокумента,
врДокументы.СуммаОплаты КАК СуммаОплаты,
врКурсыВалютаНаДатыДокументов.Курс КАК Курс,
врКурсыВалютаНаДатыДокументов.Кратность КАК Кратность
ИЗ
врДокументы КАК врДокументы
ВНУТРЕННЕЕ СОЕДИНЕНИЕ врКурсыВалютаНаДатыДокументов КАК врКурсыВалютаНаДатыДокументов
ПО (врДокументы.Дата = врКурсыВалютаНаДатыДокументов.Дата
И врДокументы.ВалютаДокумента = врКурсыВалютаНаДатыДокументов.ВалютаДокумента)

Думаю прочитав запрос - все вопросы отпадут!

Спасибо, брат)